[Search for users]
[Overall Top Noters]
[List of all Conferences]
[Download this site]
| Title: | FOCUS, from INFORMATION BUILDERS |
|
| Moderator: | ZAYIUS::BROUILLETTE |
|
| Created: | Thu Feb 19 1987 |
| Last Modified: | Mon May 05 1997 |
| Last Successful Update: | Fri Jun 06 1997 |
| Number of topics: | 615 |
| Total number of notes: | 1779 |
586.0. "Duplicates" by UBOHUB::FARRANTL (Lee Farrant) Thu Aug 11 1994 11:35
Hello again
I seem to have the same records appearing in my report
and I cannot seem to see where I have made a mistake.
Output and Fex follow.
I N T E R O F F I C E M E M O R A N D U M
Date: 11-Aug-1994 16:31BST
From: FARRANTL
FARRANTL@NICEST@NICES@UBOHUB@MRGATE@LARVAE@UCG
Dept:
Tel No:
Doc No: 013540
TO: FARRANTL@A1_UBOHUB
Subject: British Gas Rpt
1 PAGE 1
British Gas
Daily Open and Closed Service Requests
Report date 11-AUG-1994 14:29:00
Customer Log No. System Type Option or Product [O]pen or [C]losed
-------- ------- ----------- ----------------- ------------------
LEEFARRAT 00004 LEE C
LEEFARRAT 00004 LEE C
LISALTD 00006 LISA C
LISALTD 00006 LISA C
-----------------------------------------------------------------------
00005 F
00005 F
45127 F
-----------------------------------------------------------------------
CASTLECEM 00001 V3600 QQVMS O
CASTLECEM 00002 V3600 QQVMS O
BANKERSTR 00003 WEIFH O
-----------------------------------------------------------------------
*** DIGITAL - COMPANY CONFIDENTIAL ***
1 PAGE 1
British Gas
Daily Count
Report Date 9-AUG-1994 00:00:00
Sub Total
- ---------
C 4
F 3
O 3
=======================================================================
I N T E R O F F I C E M E M O R A N D U M
Date: 11-Aug-1994 16:31BST
From: FARRANTL
FARRANTL@NICEST@NICES@UBOHUB@MRGATE@LARVAE@UCG
Dept:
Tel No:
Doc No: 013539
TO: FARRANTL@A1_UBOHUB
Subject: British Gas Fex
-*****************************************************************************
-*PROCEDURE - BGAS.FEX
-*AUTHOR - LEE FARRANT
-*FUNCTION - UK & IRELAND OUT OF HOURS RESOURCE CONTROL
-*
-*DATE - 11-August-1994
-*
-*DESCRIPTION - DAILY BRITISH GAS OPEN AND CLOSED REPORT
-*
-*INPUTS - REQUST_O
-* REQUST_C
-*
-*OUTPUTS - BGAS.RPT
-* BGAS.RPT
-*
-****************************************************************************-****************************************************************************
-SET &SYS_DT = GETSTIME('A8');
-SET &DT_N_TIME = CVTSTIME(4,&SYS_DT,'A22');
-SET &DAT_N_TIME = EDIT(&DT_N_TIME,'$$99$99$99$99$99$99');
-SET &DATE_N_TIME = IF EDIT(&DAT_N_TIME,'$$$$9$') EQ ' ' THEN
- EDIT(&DAT_N_TIME,'9999$') | '0' | EDIT(&DAT_N_TIME,'$$$$$9999999') ELSE
- &DAT_N_TIME;
-SET &SHORTDATE = EDIT(&DATE_N_TIME,'999999');
-VMS DELETE [FARRANTL.BRITISH-GAS]BGAS.RPT;*
FILEDEF REQUST_O DISK REQUST_O
FILEDEF REQUST_C DISK REQUST_C
FILEDEF OFFLINE DISK [FARRANTL.BRITISH-GAS]BGAS.RPT
OFFLINE
DEFINE FILE REQUST_O
A/A20=REQU_RQ_RCVD;
AA/A3=EDIT(A,'$$$999$');
B/A2=DECODE AA ( JAN 01 FEB 02 MAR 03 APR 04 MAY 05 JUN 06 JUL 07
AUG 08 SEP 09 OCT 10 NOV 11 DEC 12 );
C/I6=(EDIT(EDIT(A,'$$$$$$$$$99') | B)*100) + EDIT(EDIT(A,'99$'));
G/A20=REQU_RQ_CLSD;
GG/A3=EDIT(G,'$$$999$');
H/A2=DECODE GG ( JAN 01 FEB 02 MAR 03 APR 04 MAY 05 JUN 06 JUL 07
AUG 08 SEP 09 OCT 10 NOV 11 DEC 12 );
I/I6=(EDIT(EDIT(A,'$$$$$$$$$99') | H)*100) + EDIT(EDIT(G,'99$'));
FLAG/A1=IF &SHORTDATE EQ C THEN 'Y' ELSE IF &SHORTDATE EQ I THEN 'Y' ELSE 'N';
END
TABLE FILE REQUST_O
PRINT REQU_CUS_SSN
REQU_LOG_NO
REQU_CONFTYP
REQU_OPT_NO
REQU_CUS_NAM
REQU_RQ_STAT
REQU_RQ_RCVD
REQU_RQ_CLSD
FLAG
IF FLAG EQ 'Y'
IF RECORDLIMIT EQ 10
ON TABLE HOLD AS BGAS1
END
-RUN
-*****************************************************************************
-* SET PARAMS FOR 0 RECORD CHECKING LATER ON
-*****************************************************************************
-SET &OPNCALLS = &RECORDS;
DEFINE FILE REQUST_C
D/A20=REQU_RQ_RCVD;
DD/A3=EDIT(D,'$$$999$');
E/A2=DECODE DD ( JAN 01 FEB 02 MAR 03 APR 04 MAY 05 JUN 06 JUL 07
AUG 08 SEP 09 OCT 10 NOV 11 DEC 12 );
F/I6=(EDIT(EDIT(D,'$$$$$$$$$99') | E)*100) + EDIT(EDIT(D,'99$'));
J/A20=REQU_RQ_RCVD;
JJ/A3=EDIT(J,'$$$999$');
K/A2=DECODE JJ ( JAN 01 FEB 02 MAR 03 APR 04 MAY 05 JUN 06 JUL 07
AUG 08 SEP 09 OCT 10 NOV 11 DEC 12 );
L/I6=(EDIT(EDIT(J,'$$$$$$$$$99') | K)*100) + EDIT(EDIT(J,'99$'));
FLAG/A1=IF &SHORTDATE EQ F THEN 'Y' ELSE IF &SHORTDATE EQ L THEN 'Y' ELSE 'N';
END
TABLE FILE REQUST_C
PRINT REQU_CUS_SSN
REQU_LOG_NO
REQU_CONFTYP
REQU_OPT_NO
REQU_CUS_NAM
REQU_RQ_STAT
REQU_RQ_RCVD
REQU_RQ_CLSD
FLAG
IF FLAG EQ 'Y'
IF RECORDLIMIT EQ 10
ON TABLE HOLD AS BGAS2
END
-RUN
-*****************************************************************************
-* SET PARAMS FOR 0 RECORD CHECKING LATER ON
-*****************************************************************************
-SET &CLSDCALLS = &RECORDS;
-*****************************************************************************
-* IF THE OPEN AND CLOSED DATABASE HAS NO RECORD MATCHES THEN GOTO INCLUDE
-* NO CALLS HEADER.
-*****************************************************************************
-IF &CLSDCALLS + &OPNCALLS EQ 0 THEN GOTO NORECS;
-*****************************************************************************
-* IF NO OPENS CALLS THEN DON'T VMS APPEND FILES
-*****************************************************************************
-IF &OPNCALLS EQ 0 THEN GOTO BGAS2;
-*****************************************************************************
-* IF NO CLOSED CALLS THEN DON'T VMS APPEND FILES
-*****************************************************************************
-IF &CLSDCALLS EQ 0 THEN GOTO BGAS1;
-*****************************************************************************
-* MERGE FILE TOGETHER ONLY IF OPEN AND CLOSED CALLS EXIST
-*****************************************************************************
-VMS APPEND BGAS1.FTM BGAS2.FTM
-*****************************************************************************
-* DEFINE APPROPRIATE FILE, DECISION MADE EARLIER
-*****************************************************************************
-BGAS1
DEFINE FILE BGAS1
-GOTO STARTDEF;
-BGAS2
DEFINE FILE BGAS2
-STARTDEF
LOG/A5=EDIT(REQU_LOG_NO,'99999$');
END
-RUN
-*****************************************************************************
-* TABLE APPROPRIATE FILE, DECISION MADE EARLIER
-*****************************************************************************
-BGAS1
TABLE FILE BGAS1
-GOTO STARTTAB;
-BGAS2
TABLE FILE BGAS2
-STARTTAB
HEADING CENTER
"British Gas"
"Daily Open and Closed Service Requests"
"Report date <REQU_RQ_RCVD"
" "
FOOTING CENTER
"*** DIGITAL - COMPANY CONFIDENTIAL ***"
PRINT REQU_CUS_SSN AS 'Customer'
LOG AS 'Log No.'
REQU_CONFTYP AS 'System Type'
REQU_OPT_NO AS 'Option or Product'
REQU_RQ_STAT AS '[O]pen or [C]losed'
BY REQU_RQ_STAT NOPRINT
BY REQU_LOG_NO NOPRINT
ON REQU_RQ_STAT UNDER-LINE
END
-*****************************************************************************
-* IF NO OPENS CALLS THEN DON'T VMS APPEND FILES
-*****************************************************************************
-IF &OPNCALLS EQ 0 THEN GOTO BGAS22;
-*****************************************************************************
-* IF NO CLOSED CALLS THEN DON'T VMS APPEND FILES
-*****************************************************************************
-IF &CLSDCALLS EQ 0 THEN GOTO BGAS11;
-*****************************************************************************
-* DEFINE APPROPRIATE FILE, DECISION MADE EARLIER
-*****************************************************************************
-BGAS11
DEFINE FILE BGAS1
-GOTO STARTDEF1;
-BGAS22
DEFINE FILE BGAS2
-STARTDEF1
LOG/A5=EDIT(REQU_LOG_NO,'99999$');
END
-RUN
-*****************************************************************************
-* TABLE APPROPRIATE FILE, DECISION MADE EARLIER
-*****************************************************************************
-BGAS11
TABLE FILE BGAS1
-GOTO STARTTAB1;
-BGAS22
TABLE FILE BGAS2
-STARTTAB1
HEADING CENTER
"British Gas"
"Daily Count"
"Report Date <REQU_RQ_RCVD "
" "
COUNT LOG AS 'Sub Total'
BY REQU_RQ_STAT AS ' '
END
-RUN
-GOTO FINUP;
-*****************************************************************************
-* COPY 'NO CALLS' BANNER TO OUTPUT FILE TO REPLACE
-*****************************************************************************
-NORECS
-VMS COPY BGAS_NORECORDS.TXT BGAS.RPT
-FINUP
-*****************************************************************************
-* MAIL FINAL REPORT TO BGAS.DIS
-*****************************************************************************
-VMS MAIL/SUBJ="DAILY BRITISH GAS REPORT" BGAS.RPT @BGAS.DIS
-VMS PURGE BGAS*.*
-FIN
| T.R | Title | User | Personal
Name | Date | Lines |
|---|
| 586.1 | If you data HAS dupes, try this | BRAT::WEHIKE::Clark | | Wed Sep 07 1994 11:36 | 21 |
| Do you have duplicate lines of data in your intermediate hold files. If so, you need to sum some innocuous
variable by the fields you wish to print out to remove the dupes.
i.e. sum type
by col1_name
by col2_name
etc
on table hold as something
end
table file something
print col1 col2 col3 etc
the dupes are gone, then
good luck if still a problem.
If you DON'T have dupes in the file to begin with, I haven't a clue.
With certs or revenue data or customer information ( which I usually work with) frequently there are multiple
occurences of the field combinations in the data file. I don't know about your data.
|